thegeneralist01/config
1
Fork 0
mirror of https://github.com/thegeneralist01/config.git synced 2026-10-09 21:03:30 +02:00
Code Issues Activity

nixos: migrate server services to thegeneralist

Browse source 
Move hosted services and secrets from the retired central hosts, persist USB storage and ownership, harden RTL8822BU Wi-Fi, repair DNS behavior, and order CoreDNS after Tailscale.
This commit is contained in:
TheGeneralist 2026-10-09 14:21:55 +02:00
parent 7f5ecd917b
commit bd887883f7
Signed by: thegeneralist01
SSH key fingerprint: SHA256:pp9qddbCNmVNoSjevdvQvM5z0DHN7LTa8qBMbcMq/R4
41 changed files with 183 additions and 511 deletions
Download patch file Download diff file Expand all files Collapse all files

80
hosts/thegeneralist/jellyfin/default.nix Normal file
View file

@ -0,0 +1,80 @@
{ pkgs, ... }:
let
acmeDomain = "thegeneralist01.com";
domain = "internal.${acmeDomain}";
ssl = {
forceSSL = true;
quic = true;
useACMEHost = domain;
};
in
{
environment.systemPackages = with pkgs; [
jellyfin
jellyfin-web
jellyfin-ffmpeg
];
services.jellyfin = {
enable = true;
package = pkgs.jellyfin;
group = "jellyfin";
user = "jellyfin";
cacheDir = "/mnt/usb/services/jellyfin/cache";
dataDir = "/mnt/usb/services/jellyfin/data/data";
configDir = "/mnt/usb/services/jellyfin/data/config";
logDir = "/mnt/usb/services/jellyfin/data/log";
};
systemd.services.jellyfin = {
requires = [ "jellyfin-data-ownership.service" ];
after = [ "jellyfin-data-ownership.service" ];
};
systemd.services.jellyfin-data-ownership = {
description = "Prepare persisted Jellyfin state";
unitConfig.RequiresMountsFor = [ "/mnt/usb/services/jellyfin" ];
before = [ "jellyfin.service" ];
serviceConfig.Type = "oneshot";
script = ''
marker=/mnt/usb/services/jellyfin/.nixos-ownership-v1
if [ ! -e "$marker" ]; then
${pkgs.coreutils}/bin/chown -R jellyfin:jellyfin /mnt/usb/services/jellyfin
${pkgs.coreutils}/bin/touch "$marker"
${pkgs.coreutils}/bin/chown jellyfin:jellyfin "$marker"
fi
'';
};
services.nginx.virtualHosts.${domain} = ssl // {
listen = [
{
addr = "100.108.125.63";
port = 443;
ssl = true;
}
{
addr = "100.108.125.63";
port = 80;
}
];
locations."/" = {
proxyPass = "http://127.0.0.1:8096";
recommendedProxySettings = true;
extraConfig = ''
proxy_set_header Upgrade $http_upgrade;
proxy_set_header Connection $connection_upgrade;
# tell nginx not to buffer the response. send it as it comes.
proxy_buffering off;
# give jellyfin plenty of time to transcode
proxy_read_timeout 3600s;
proxy_send_timeout 3600s;
'';
};
};
}